[脚本][原创] 新式普通选单制作教学

#include <amxmodx> // 任何AMXX需要的基本INC

public plugin_init() // 注册插件
{
    register_clcmd( "say /menu","ExtraMenu");
    // "say /menu" 为执行指令的方法 ; ExtraMenu 为 执行的Function
}
// 名为 ExtraMenu 的 Function
public ExtraMenu(id)
{
    // 新增一个单位"menu" = 建立一个选单
    new menu = menu_create("\r选单名称", "menu_handler");
    // 第一格为名称 
    // 白色 = \w 
    // 黄色 = \y 
    // 红色 - \r 
    // 灰色 - \d 
    // 第二格为指令所去的Function

    // 新增Menu的选项
    menu_additem(menu, "\w Selection #1", "1", ADMIN_LEVEL_A);
    menu_additem(menu, "\w Selection #2", "2", 0);
    menu_additem(menu, "\w Selection #3", "3", 0);
    // menu为刚才新增的参数
    // \w Selection #1 为 第一项选项
    // 第三格 "1" 为 排在选单第几项
    // ADMIN_LEVEL_A 是指执行的权限 , 详细可阅USER.INI取得更多资讯
    // 如果填写为 0 是指任何人适用

    // 设定此Menu 的离开位置和转页
    menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);


    // 显示选单
    menu_display(id, menu, 0);

    // 自主性决定吧 如果使用 say 指令会显示字在说话频道 如果不想可加上这一行
   // 把 // Del去就行
   // return PLUGIN_HANDLED;
}

// 刚才设定此Function为按键的设凡
public menu_handler(id, menu, item)
{
    // 如果按离开会发生的事
    if( item == MENU_EXIT )
    {
        // 消除选单
        menu_destroy(menu); 
        return PLUGIN_HANDLED;
    }

    // 新增一些为玩家设定的参数
    new data[6], iName[64];
    new access, callback;

    // 取得玩家的权限 及 其资料
    menu_item_getinfo(menu, item, access, data,5, iName, 63, callback);

    // 将你所按的键转换成Number
    new key = str_to_num(data);

    // 列出Number所发生的事
    switch(key)
    {
        case 1:
        {
            client_print(id, print_chat, "你按了按键一");
            menu_destroy(menu);        // 消除选单
            return PLUGIN_HANDLED;        // 离开插件
        }
        case 2:
        {
            client_print(id, print_chat, "你按了按键2");
            menu_destroy(menu);        // 消除选单
        return PLUGIN_HANDLED;        // 离开插件
        }
        case 3:
        {
            client_print(id, print_chat, "你按了按键3");
            menu_destroy(menu);        // 消除选单
        return PLUGIN_HANDLED;        // 离开插件
        }
    }

    // 消除选单
    menu_destroy(menu);
    //  离开插件
    return PLUGIN_HANDLED;
}