#include <amxmodx>
#include <oo>

public plugin_init()
{
       // 挂钩 Animal@Ctor() 的建构子
       oo_hook_ctor("Animal", "Ctor", "OnAnimalCtor");

       // 挂钩 Dog@MakeSound() 方法 (post事件)
       oo_hook_mthd("Dog", "MakeSound", "OnDogMakeSound_Post", 1);

       // 挂钩 Snake@GetLegs() 方法
       oo_hook_mthd("Snake", "GetLegs", "OnSnakeGetLegs_1");
       oo_hook_mthd("Snake", "GetLegs", "OnSnakeGetLegs_2");

       // 挂钩 Snake@Test() 方法
       oo_hook_mthd("Snake", "Test", "OnSnakeTest");

       // 挂钩 Animal@Dtor() 的解构子
       oo_hook_dtor("Animal", "OnAnimalDtor");
}

public OnAnimalCtor(const name[], age)
{
       server_print("OnAnimalCtor(name=%s, age=%d)", name, age);
}

public OnDogMakeSound_Post(msg[], len)
{
       server_print("OnDogMakeSound_Post(msg=%s, len=%d)", msg, len);
}

public OnSnakeGetLegs_1()
{
       server_print("OnSnakeGetLegs_1()");
       oo_hook_set_return(369); // 改变这方法原本回传的值
       return OO_CONTINUE;
}

public OnSnakeGetLegs_2()
{
       server_print("OnSnakeGetLegs_2() => oo_hook_get_return()=%d", 
              oo_hook_get_return()); // 获取之前改变了的回传值

       return OO_SUPERCEDE; // 阻止原本这方法的执行
}

public OnSnakeTest(a, &b, const c[], d[], e[5])
{
       server_print("OnSnakeTest(%d, %d, %s, %s, {%d,%d,%d,%d,%d})", a, b, c ,d, e[0], e[1], e[2], e[3], e[4]);

       // 改变第 1 个参数 a 的值做 11
       oo_hook_set_param(1, OO_CELL, 11);

       // 改变第 2 个参数 b 的值做 22 (因为类型是 OO_BYREF 可以直接改)
       b = 22;

       // 改变第 3 个参数 c 的值做 "33"
       oo_hook_set_param(3, OO_STRING, "33");

       // 改变第 4 个参数 d 的值做 "44" (因为类型是 OO_STRING_REF 可以直接改)
       copy(d, 31, "44");

       // 改变第 5 个参数 e 的值做 {11, 22, 33, 44, 55}
       new arr[5] = {11, 22, 33, 44, 55};
       e = arr; // 因为类型是 OO_ARRAY 可以直接改
}

public OnAnimalDtor()
{
       server_print("OnAnimalDtor()");
}